on *:START:{
  /set %cafeNick YOURNICK
  /set %cafePassword YOURPASSWORD
  /set %cafeConnectOnStartup Yes
  /set %cafeJoinTheGoldCafe Yes

  if (%cafeConnectOnStartup == Yes) {
    /server irc.star-fleet.net
  }
}

on *:CONNECT:{
  if ($network == starfleet) {
    if ($me != %cafeNick) /nick %cafeNick
    if (%cafeJoinTheGoldCafe == Yes) {
      .timer 1 30 if ( $me !ison #TheGoldCafe ) /join #TheGoldCafe
    }
    .timer 1 60 if ( $me !ison #TheRomCafe ) /join #TheRomCafe
    .timer 1 65 if ( $me !ison #TheRomCafe ) /server irc.star-fleet.net
  }
}

raw 433:*Nickname is already in use*: {
  if ($network == starfleet) {
    /timer 1 3 /msg nickserv ghost %cafeNick %cafePassword
  }
}
on *:NOTICE:*Ghost with your nick has been killed*:?: {
  if ($network == starfleet) && ($nick == nickserv) {
    /nick %cafeNick
  }
}
on *:NOTICE:*Nick %cafeNick isn't currently in use*:?: {
  if ($network == starfleet) && ($nick == nickserv) {
    /nick %cafeNick
  }
}
on *:NOTICE:*please choose a different nick*:?: {
  if ($network == starfleet) && ($nick == nickserv) {
    /msg nickserv identify %cafePassword
  }
}
on *:NOTICE:*Password accepted - you are now recognized*:?: {
  if ($network == starfleet) && ($nick == nickserv) {
    if (%cafeJoinTheGoldCafe == Yes) {
      /join #TheGoldCafe
    }
    /join #TheRomCafe
  }
}

menu status {
  Visit #TheRomCafe : /server irc.star-fleet.net
}

on *:FILERCVD:*: {
  /rename " $+ $filename $+ " " $+ $nofile($filename) $+ $replace($nopath($filename),_,$chr(32)) $+ "
}